/** SelectFilter.Script.txt a MapEditorPlugin for tm2020 
*
* update 2022-05-22: make search ignore letter case and ignore ground for "grass".
* update 2022-12-27: fix manialink z-index
*
* usage: Enable plugin and press Ctrl-F to filter out blocks on map.
*
*/

#RequireContext CMapEditorPlugin
#Include "TextLib" as TL
#Const Version "1.0.1"

main() {    
    LayersDefaultManialinkVersion = 3;
    ManialinkText = """
    <frame id="filterFrame" hidden="1" pos="0 30" scale="0.8">
    <label text="Filter by" pos="0 6" halign="center" valign="center" />
    <entry id="filter" pos="0 0" size="40 5" default="" valign="center" halign="center"  />    	
    <label id="Apply" pos="-15 -6" size="20 5" text="Apply" valign="center" halign="center" style="CardButtonSmallS" scriptevents="1" /> 
    <label id="Close" pos="15 -6" size="20 5" text="Close" valign="center" halign="center" scriptevents="1" style="CardButtonSmallS" /> 
    <quad halign="center" valign="center" size="60 20" bgcolor="000a" z-index="-1" />
    </frame>
    <frame id="waitDialog" pos="0 0" scale="0.8" hidden="1">
    <label text="PLEASE WAIT..." pos="0 0" halign="center" valign="center" />
    <quad z-index="-1" halign="center" valign="center" size="60 20" bgcolor="000a"/>
    </frame>
    <script><!--
    main() {        
        declare CMlFrame frame = Page.GetFirstChild("filterFrame") as CMlFrame;
        while (True) {
            yield;
            foreach (Event in PendingEvents) {
                if (Event.Type == CMlScriptEvent::Type::EntrySubmit) {		
                    SendCustomEvent("gogo", []);	
                    frame.Hide();
                }
                if (Event.Type == CMlScriptEvent::Type::KeyPress) {									
                    if (Input.IsKeyPressed(65) && Event.KeyName == "F") {
                        frame.Visible = !frame.Visible; 
                        if (frame.Visible) {
                            (Page.GetFirstChild("filter") as CMlEntry).Value = "";
                            Page.GetFirstChild("filter").Focus();
                            SendCustomEvent("changeMode", []);														
                        }
                    }            
                }
                if (Event.Type == CMlScriptEvent::Type::MouseClick) {
                    if (Event.ControlId == "Apply") {
                        SendCustomEvent("gogo", []);	
                        frame.Hide();
                    }
                    if (Event.ControlId == "Close") {
                        frame.Hide();
                    }
                }		
            }
        }
    }
    --></script>
    
    
    """;
    
    while (True) {
        yield;
        foreach (Event in PendingEvents) {            
            switch (Event.Type) {                
                case CMapEditorPluginEvent::Type::LayerCustomEvent: {
                    if(Event.CustomEventType == "changeMode") {	 
                        PlaceMode = CMapEditorPlugin::PlaceMode::CopyPaste;
                    }
                    if(Event.CustomEventType == "gogo") {	 						
                        declare Text value = (ManialinkPage.MainFrame.GetFirstChild("filter") as CMlEntry).Value;	
                        declare CMlFrame waitDialog = (ManialinkPage.MainFrame.GetFirstChild("waitDialog") as CMlFrame);                                                
                        if (value == "") continue;                        							
                        CopyPaste_ResetSelection();                        
                        declare Integer counter = 0;
                        waitDialog.Show();
                        foreach (block in Blocks) {
														if (block.BlockModel.Name == "Grass") continue;                        
                            declare Text[] match = TL::RegexMatch(TL::ToLowerCase(value), TL::ToLowerCase(block.BlockModel.Name), "");
														
                            if (match[0] == TL::ToLowerCase(value)) {														
                                if (counter >= 200) {
                                    counter = 0;
                                    yield;
                                }
                                
                                CopyPaste_AddOrSubSelection(block.Coord, block.Coord);
                                counter +=1;		
                            }                            
                        }
                        waitDialog.Hide();
                    }
                }
            }
        }
    }
}